get #184

Parent #93Owner #361Flags readSource hellcore/hellcore.db

Aliases: get

6 verbs · 19 properties · 0 children

Verbs

Properties

Ancestry

• #1 root

  • #93 Generic Action

    • #184 get

Ancestors (nearest first): #93 Generic Action → #1 root

Children: none

Call graph

Source

"$actions.get:_start(OBJ who, LIST callback) =>";
"  Causes who to queue try to begin picking something, or perhaps lots";
"  of things, up, or to remove them from whatever container they happen";
"  to be in.";
"The callback args are as follows:";
"  { LIST what [, OBJ container [, LIST picked_up ]] }";
"    what is simply a list of objects to try to get";
"    container is the container that the objects are coming out of";
"    picked_up is a list of objects we've already picked up in this";
"      get 'session', meaning continuous successive get actions.";
who = args[1];
callback = args[2];
what = callback[1];
container = (length(callback) > 1) ? callback[2] | #-1;
picked_up = (length(callback) > 2) ? callback[3] | {};
first_get = picked_up ? 0 | 1;
total_weight = 0;
"Quick sanity check on the args to make sure we've got a list";
if (typeof(what) == OBJ)
what = {what};
endif
"Now figure out from the list of potential targets we can get";
"We prune the list of 'gettable' objects on each successive get,";
"  since the they may no longer be around or otherwise indisposed";
"  in the time that has passed since the last get finished.";
picking_up = {};
for item in (what)
if (!(item.location in {who.location, container}))
"";
elseif (!(m = who:cant_take(item)))
picking_up = listappend(picking_up, item);
else
who:tell("You can't get ", item:dname(), " because ", m, ".");
endif
$cu:sin();
endfor
if (!picking_up)
return E_INVARG;
endif
"If this is the first get action in a get session then we need";
"  to print a message to the room about what's happening.  There";
"  is quite a lot of special casing here in the name of better";
"  readability.";
if (valid(container) && (container.location == who))
pronoun = who.pp;
else
pronoun = "the";
endif
if (first_get)
"Map the unique inames to the objects we're picking up";
names = $su:message_db(picking_up, "iname");
namestrs = {};
for x in (names)
if (len = length(x[1]) > 1)
namestrs = listappend(namestrs, x[1][1]:pname(len));
else
namestrs = listappend(namestrs, x[2]);
endif
endfor
if (length(namestrs) > 1)
things = "things";
else
things = picking_up[1]:pname();
endif
if (length(picking_up) > 3)
if ($api.container:is_on(container))
who:aat(((((((who:dnamec() + " starts pulling ") + things) + " out of ") + pronoun) + " ") + container:name()) + ".");
else
who:aat(((who:dnamec() + " starts picking ") + things) + " up.");
endif
elseif (length(picking_up) > 1)
"We have the list of inames, why not use it if it's not too spammy?";
if ($api.container:is_on(container))
who:aat(((((((who:dnamec() + " starts getting ") + $su:english_list(namestrs)) + " from ") + pronoun) + " ") + container:name()) + ".");
else
who:aat(((who:dnamec() + " starts picking up ") + $su:english_list(namestrs)) + ".");
endif
endif
endif
"Note that we're passing a possibly revised version of the callback";
"  args for the :_finish verb to use.  This saves some pruning time";
"  on the back end and also keeps messages from being printed twice.";
who.location:broadcast_event(1, $actions.get, who, {picking_up[1], container});
return {this:duration(), {picking_up, container, picked_up}};

"$actions.get:_finish(OBJ who, LIST callback, LIST from_start) =>";
"  This verb is the second phase of the get action.  It actually";
"  completes the transaction, moving the object in question into";
"  the person doing the getting.";
who = args[1];
callback = args[2];
what = callback[1];
"We are ignoring the callback args in favor of the data we get from";
"  the :_start verb, which may have already pruned a bunch of crap";
"  that we no longer need to deal with.  This comes to us as args[3].";
from_start = args[3];
picking_up = $lu:remove_if_not($rpg, "valid", from_start[1]);
picked_up = $lu:remove_if_not($rpg, "valid", from_start[3]);
container = from_start[2];
for x in (picking_up)
m = who:cant_take(x);
if (typeof(m == STR))
picking_up = setremove(picking_up, x);
endif
endfor
if (picking_up)
target = picking_up[1];
picking_up = listdelete(picking_up, 1);
if (who:_get(target, container))
picked_up = listappend(picked_up, target);
else
target = #-1;
endif
elseif (picked_up)
target = picked_up[$];
else
target = #-1;
endif
"All of this calculation around the inames of the objects we're dealing";
"  with is just to figure out if this is a 'homogenous' get, meaning";
"  we are picking up multiple objects of a single type.";
"We figure out whether this is the case by mapping the unique inames to";
"  the objects in question, then seeing how many unique names we actually";
"  have.  If it's more than one, then there must have been more than one";
"  object type.";
names = $su:message_db(picked_up, "iname");
namestrs = {};
if (valid(container) && (container.location == who))
pronoun = who.pp;
else
pronoun = "the";
endif
for x in (names)
namestrs = listappend(namestrs, ((len = length(x[1])) > 1) ? x[1][1]:pname() | x[2]);
endfor
"If they are picking up multiple kinds of things, we just refer to it";
"  collectively as 'stuff' or 'things'.";
if ((length(namestrs) > 1) || (!namestrs))
things = "stuff";
else
things = namestrs[1];
endif
"And now the actual announcement of the appropriate messages.  There are";
"  two cases when we actually want to announce something:";
"  -- When we are finished picking up everything we could";
"  -- Every five get actions, to let people know it's still happening";
"First we handle the case of printing a message every five gets. Note";
"  that if we have nothing left to pick up this won't get printed, and";
"  will be caught by the other case instead.";
if (picking_up && valid(target))
if (!(length(picking_up) % 5))
if (length(names) > 1)
if ($ou:has_verb(container, "get_from") && $ou:has_verb(container, "cant_get_from"))
who.location:announce_all_but({who}, ((((((((("You notice " + who:dnamec()) + " grabbing ") + target:iname()) + " as ") + who.ps) + " continues taking things out of ") + pronoun) + " ") + container:name()) + ".");
else
who.location:announce_all_but({who}, ((((("You notice " + who:dnamec()) + " grabbing ") + target:iname()) + " as ") + who.ps) + " continues picking things up.");
endif
else
if ($ou:has_verb(container, "get_from") && $ou:has_verb(container, "cant_get_from"))
who.location:announce_all_but({who}, ((((((who:dnamec() + " continues taking ") + things) + " out of ") + pronoun) + " ") + container:name()) + ".");
else
who.location:announce_all_but({who}, ((who:dnamec() + " continues picking up ") + things) + ".");
endif
endif
endif
who:queue_action(this, {picking_up, container, picked_up}, 0, (this.name + " ") + picking_up[1]:name());
else
"If we made it here it's because we have nothing left to pick up.  In";
"  this case we print messages to the room to let everyone know that";
"  we're done picking things up.";
if (length(picked_up) > 3)
if ($ou:has_verb(container, "get_from") && $ou:has_verb(container, "cant_get_from"))
who:aat(((((((who:dnamec() + " stops pulling ") + things) + " out of ") + pronoun) + " ") + container:name()) + ".");
else
who:aat(((who:dnamec() + " seems to have finished picking up ") + things) + ".");
endif
elseif (length(picked_up) > 1)
if ($ou:has_verb(container, "get_from") && $ou:has_verb(container, "cant_get_from"))
who:aat(((((((who:dnamec() + " finishes getting ") + $su:english_list(namestrs)) + " from ") + pronoun) + " ") + container:name()) + ".");
else
who:aat(((who:dnamec() + " finishes picking up ") + $su:english_list(namestrs)) + ".");
endif
elseif (valid(target))
if ($ou:has_verb(container, "get_from") && $ou:has_verb(container, "cant_get_from"))
if (!(m = container.get_from_msg))
m = ("%DN gets %id from " + pronoun) + " %t.";
endif
who:aat($su:ps(m, who, container, who.location, target, container));
elseif (target.location == who)
m = who.get_msg ? who.get_msg | (`tm = target:get_msg() ! ANY => 0' ? tm | who.location.get_msg);
who:aat($su:ps(m, who, target, target, who));
endif
endif
endif

who = args[1];
if (args[2])
callback = args[2];
what = callback[1];
container = (length(callback) > 1) ? callback[2] | #-1;
if (typeof(what) == LIST)
if ($api.container:is_on(container))
return "getting some things from " + container:iname();
else
return "picking some things up";
endif
else
if ($api.container:is_on(container))
return (("getting " + what:iname()) + " from ") + container:iname();
else
return "picking up " + what:iname();
endif
endif
else
return "getting";
endif

who = args[1];
what = args[2];
container = args[3];
if (typeof(what) == LIST)
who:_get_many_from_container(what);
else
if ((container.location == who.location) || (container.location == who))
who:_get_from_container(what, container);
endif
endif

"$actions.get:_abort(OBJ who, LIST callback, LIST from_start) =>";
"  This verb handles the case of players aborting their get action before";
"  it is actually completed.  All we need to do is print the appropriate";
"  messages.";
who = args[1];
callback = args[2];
what = callback[1];
container = (length(callback) > 1) ? callback[2] | #-1;
picked_up = (length(callback) > 2) ? callback[3] | {};
if (picked_up)
names = $su:message_db(picked_up, "iname");
namestrs = {};
for x in (names)
if (len = length(x[1]) > 1)
namestrs = listappend(namestrs, x[1][1]:pname(len));
else
namestrs = listappend(namestrs, x[2]);
endif
endfor
if (length(namestrs) > 1)
things = "stuff";
else
things = namestrs[1];
endif
if ($api.container:is_on(container))
who:aat(((((((who:dnamec() + " stops getting ") + things) + " from ") + who.pp) + " ") + container:name()) + ".");
else
who:aat(((who:dnamec() + " stops picking ") + things) + " up.");
endif
endif

who = args[1];
what = args[2];
for x in ({who.executing, @who.queue})
if (x && (x[1] == $actions.get))
callback = x[2];
picking_up = callback[1];
container = callback[2];
picked_up = callback[3];
if (what in picking_up)
return 1;
endif
endif
endfor