generic quest #166

award_to

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

none

Source

wholist = (typeof(args[1]) == LIST) ? args[1] | {args[1]};
earned = 0;
for who in (wholist)
if ((is_a(who, $player) && (who:area() != #1436)) && who.xp_total)
if (!(this in who.quest_xp))
if (m = this.earn_msg)
who:tell($ansi.bold_on, m, $ansi.reset);
endif
who:tell(tostr($ansi.bold_on, "You earned the '", this:name_for(who), "' XP award!", $ansi.reset));
$nets.questnet:announce(who, tostr(this.net_color, who.name, " earned the '", this.name, "' quest award for ", this.xp_award, " XP.", $ansi.reset), 1);
who:award_xp(this.xp_award);
"if (c = this.credit_award)";
"  who:credit_receive(c, #-1);";
"endif";
awards = this.item_award;
if (typeof(awards) != LIST)
awards = {awards};
endif
for item in (awards)
if (valid(item))
item = $rpg:spawn(item);
if (who:get_gift(item, #-1))
who:tell($ansi.bold_on + "You got ", item:iname(), "!", $ansi.reset);
else
item:moveto(who.location);
who:tell($ansi.bold_on + "You got ", item:iname(), " but couldn't take it!  It's on the ground.", $ansi.reset);
endif
endif
endfor
if (!who.quest_xp)
who:tell(($ansi.bold_on + "To view your unique XP awards, type 'journal'.") + $ansi.reset);
endif
who.quest_xp = setadd(who.quest_xp, this);
if (this in keys(who.quests))
who.quests = hashremove(who.quests, this);
endif
this.earned_by = setadd(this.earned_by, who);
if (this.news_msg && (!is_a(who, $immortal)))
$rpg.news:add_quest(this, who);
endif
this:_award_to(who);
if (!$recycler:valid(who.respawn))
who.respawn = who:default_respawn();
endif
if (((or = who.respawn) != $player_start) && (!$ou:has_verb(or, "update_clone")))
who.respawn = who:default_respawn();
$nets.prognet:announce(#2, ($su:nn(who) + " had weird .respawn: ") + $su:nn(or), 1);
endif
if (!$recycler:valid(who.respawn))
who.respawn = who:default_respawn();
endif
"if (!who:is_hardcore())";
"  #2800:update_clone(who);";
"endif";
earned = earned + 1;
endif
endif
endfor
return earned;

_award_to

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

• #166:award_to line 41: this:_award_to

Source

if ((this != this.metaquest) && is_a(this.metaquest, #37269))
this.metaquest:should_award_to(args[1]);
endif

remove_from

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

none

Source

{who, ?force = 0} = args;
wholist = (typeof(who) == LIST) ? who | {who};
dont_remove = {#183254};
if ((!force) && (this in dont_remove))
return 0;
endif
removed = 0;
for p in (wholist)
$cu:sin(0);
if (is_a(p, $player))
if ((this in p.quest_xp) || (p in this.earned_by))
xp = this.xp_award;
new_total = max(1, p.xp_total - xp);
new_unspent = min(0, p.xp - xp);
if (0 && ((new_total < 0) || (new_unspent < 0)))
raise(E_INVIND);
endif
p.quest_xp = setremove(p.quest_xp, this);
this.earned_by = setremove(this.earned_by, p);
p.xp_total = new_total;
p.xp = new_unspent;
removed = removed + 1;
endif
endif
endfor
return removed;

tree_tag

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

none

Source

r = "";
if (this.survive_reroll)
r = tostr(r, " ", $ansi.blue, $ansi.bold_on, "!", $ansi.reset);
endif
if (this.xp_award)
r = tostr(r, " ", this.xp_award, "XP");
endif
if ((typeof(this.item_award) == OBJ) && valid(this.item_award))
r = tostr(r, " ", $su:nn(this.item_award));
endif
if ($recycler:valid(this.metaquest))
r = ((r + " ") + "metaquest: ") + $su:nn(this.metaquest);
endif
if ("_award_to" in verbs(this))
r = r + " _award_to";
endif
if (this.net_color)
r = (((r + " ") + this.net_color) + "questnet") + $ansi.reset;
endif
return r;

remove_from_all

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

• #166:recycle line 1: this:remove_from_all

Source

if ((!valid(cp = caller_perms())) || (!$perm_utils:controls(cp, this)))
return {};
endif
earned = this.earned_by;
removed = {};
for x in (this.earned_by)
if (is_a(x, $player) && (this in x.quest_xp))
x.quest_xp = setremove(x.quest_xp, this);
removed = setadd(removed, x);
earned = setremove(earned, x);
endif
$cu:sin(1);
endfor
this.earned_by = earned;
return removed;

recycle

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

none

Source

this:remove_from_all();
return pass(@args);

rumors

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

none

Source

r = {};
for x in ($ou:leaves($rumor))
if (x.quest == this)
r = setadd(r, x);
endif
endfor
return r;

earned_by

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

none

Source

{who} = args;
if (!is_a(who, $player))
return 0;
elseif (!(this in who.quest_xp))
return 0;
endif
return who in this.earned_by;

change_value

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

none

Source

oldvalue = this.xp_award;
newvalue = args[1];
this.xp_award = newvalue;
for x in (this.earned_by)
x:award_xp(newvalue - oldvalue);
$cu:sin(0);
endfor

add_hint

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

none

Source

{who, hint, ?announce = 0} = args;
hint = $ansi:strip(hint);
if (this in who.quest_xp)
return;
endif
if (announce)
who:systell(hint);
endif
first = (!who.quests) ? 1 | 0;
if (!(this in keys(who.quests)))
who.quests[this] = {};
endif
hints = who.quests[this];
if (!(hint in $lu:slice(hints, 2)))
if (!who.quests[this])
who:systell("You just got a hint about the '", this.name, "' journal.");
else
who:systell("You got another hint about '", this.name, "'.");
endif
if (first)
who:systell("To refer back to hints you've received, type 'hints'.");
endif
who.quests[this] = listappend(who.quests[this], {area(who), hint});
endif

name_for

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

• #166:award_to line 9: this:name_for

Source

{who} = args;
return this:name();

description_for

Spec this none thisFlags rxdOwner #361Definer #166

Referenced by

none

Source

{who} = args;
return this.description;