Social Feature with Event Broadcasting #149

wave hug frown smile laugh

Spec any none noneFlags rxdOwner #361Definer #149

Referenced by

none

Source

if (!valid(dobj))
dobj = $mu:match(dobjstr, player.location:contents());
endif
if (dobj == #-2)
player:tell(verb, " who?");
return;
elseif (dobj == #-3)
player:tell("There is no one named \"", dobjstr, "\" here.");
return;
endif
if (((0 && (verb == "hug")) && is_a(dobj, $player)) && (dobj != player))
#270304.hug_log[dobj] = `#270304.hug_log[dobj] ! E_RANGE => 0' + 1;
endif
social = $actions.social.(verb);
this:_do_social(player, dobj, social);

_do_social

Spec this none thisFlags rxdOwner #361Definer #149

Referenced by

• #149:wave line 15: this:_do_social

Source

":_do_social(OBJ source, OBJ target, OBJ social_action | STR social_action_name);";
"Use #-1 as target if there is no target, i.e. if you just want to perform an undirected action (\"You smile.\");  Note that this doesn't always work, as some social verbs are transitive only.";
{actor, target, social} = args;
if (typeof(social) == STR)
social = $actions.social.(social);
endif
where = actor.location;
if (`where:forbid_social(actor, target, social.name) ! ANY')
return;
endif
if ((!valid(target)) && social.transitive_only)
actor:tell("You have to do that to someone in particular.");
return;
endif
msgs = [];
tangible = social.is_tangible;
audible = social.is_audible;
verb = social.name;
prep = social.preposition;
if (prep)
prep = " " + prep;
endif
if (((verb[$] == "s") || (verb[$ - 1..$] == "sh")) || (verb[$ - 1..$] == "ch"))
suffix = "es";
else
suffix = "s";
endif
"who can see?";
witnesses = {};
vague_witnesses = {};
everyone = where:occupants($creature);
for c in (everyone)
dark = where:darkness(0, c);
if ((dark in {1, 0, -1}) || (c:can_see_in_dark() && (dark > 0)))
witnesses = {@witnesses, c};
elseif (dark in {2, -2})
vague_witnesses = {@vague_witnesses, c};
endif
endfor
"if actor can't see, he may pick the wrong person.";
hopefully_target = target;
to_self = target == actor;
if (valid(target) && (!to_self))
if ((!(actor in witnesses)) && ($skills.senses:check(actor, -3 * where:darkness(0, actor)) < 0))
potentials = setremove(everyone, actor);
if (!potentials)
actor:tell("No one seems to be here...");
return;
endif
target = potentials[random($)];
elseif (!((target == where) || (target.location in {where, actor})))
actor:tell(target:dnamec(), " isn't here.");
return;
endif
endif
"get messages";
if (valid(target))
"transitive";
msgs["self"] = social.tsocial_self_msg;
msgs["others"] = social.tsocial_others_msg;
msgs["target"] = social.tsocial_target_msg;
else
"intransitive";
msg = social.social_msg;
msgs["others"] = msg;
self_msg = strsub(msg, "%DN", "You");
self_msg = strsub(self_msg, "%N", "You");
self_msg = strsub(self_msg, "%p", "your");
msgs["self"] = self_msg;
endif
for msgtype in (keys(msgs))
msg = msgs[msgtype];
msg = strsub(msg, "[verb]", verb);
msg = strsub(msg, "[prep]", prep);
msgs[msgtype] = msg;
endfor
for c in (where.contents)
if (!(has_property(c, "listening") && c.listening))
continue;
endif
eff_actor = actor;
eff_target = target;
if ((c in witnesses) || (!is_a(c, $creature)))
"ok, this person can see.";
elseif (c == actor)
eff_target = hopefully_target;
elseif ((c == target) && (((c in vague_witnesses) || audible) || tangible))
eff_actor = $someone;
elseif (audible || (c in vague_witnesses))
eff_actor = $someone;
eff_target = $someone_else;
else
continue;
endif
if (c == actor)
msg = msgs["self"];
elseif (c == target)
msg = msgs["target"];
else
msg = msgs["others"];
endif
msg = strsub(msg, "[suffix]", (c == actor) ? "" | suffix);
if (valid(eff_target))
if (to_self)
msg = strsub(msg, "[dobj]", (c == actor) ? "yourself" | eff_actor.pr);
else
msg = strsub(msg, "[dobj]", eff_target:dname());
endif
endif
msg = $su:ps(msg, eff_actor);
if (((eff_actor == $someone) && (length(msg) >= 7)) && (msg[1..7] == "someone"))
msg[1..7] = "Someone";
endif
c:tell(msg);
endfor
if (valid(target) && has_callable_verb(target, "receive_social_" + verb))
target:("receive_social_" + verb)(actor);
endif
where:broadcast_event(1, social, actor, {target});
if (is_a(social.noise, $noise))
where:make_noise(social.noise, actor, {target});
endif