wristpad #130

init

Spec this none noneFlags rxdOwner #361Definer #130

Referenced by

none

Source

"Lock this wristpad to yourself, if it's not already.";
if (this.location != player)
player:tell("You're not holding ", this:dname(), ".");
elseif ((this.registered_user == player) && (player.wristpad == this))
player:tell(this:dnamec(), " is already initialized to you.");
else
player:tell("You run the initialization sequence on ", this:dname(), " and set it up as your primary comm device.");
this.registered_user = player;
player.wristpad = this;
endif

_page

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

who = args[1];
user = this.registered_user;
if (length(args) > 1)
msg = $su:from_list(args[2..$], " ");
else
msg = "BEEP";
endif
msg = $su:escape(msg);
if (is_a(who, $wristpad))
who:_receive(player, msg);
return;
endif
if (is_player(who) && (!valid(who.wristpad)))
user:tell("Your ", this:name(), " responds: 'Cannot connect to user.'");
else
if (is_player(who))
if (is_a(who.wristpad, $wristpad))
if ((length(msg) > 250) && (!this:can_send_long_message(user, who)))
msg = msg[1..250];
user:tell("Your page exceeded safety limits and has been downsized.");
endif
who.wristpad:_receive(user, msg);
else
user:tell("Hmmm.  ", who:dnamec(), " seems completely absent from the comm network.");
endif
else
`who:page_receive(user, msg) ! E_VERBNF => 0';
endif
user:tell(((("You text '" + $ansi.bold_on) + msg) + $ansi.reset) + "' to ", who.name, " on your ", this.name, ".");
if ((this.page_msg && (!who.programmer)) && (random(100) < 10))
argstr = "naughty naughty";
user.location:announce($su:ps(this.page_msg, user, this));
endif
endif

_receive

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

{sender, text} = args;
if ((this.mode > 0) || (player in this.ignore))
"Filtering is on";
if (!player.programmer)
fork (1)
player:tell("Your wristpad beeps. ", this.registered_user.name, " must be busy.");
endfork
return;
endif
endif
m = this.page_receive_msg;
m = strsub(m, "%t", this.name);
if (is_a(sender, #109))
m = strsub(m, "%n", sender:real_name());
else
m = strsub(m, "%n", sender:dname());
endif
m = strsub(m, "%message", ($ansi.bold_on + text) + $ansi.reset);
if (valid(this.location))
this.location:tell(m);
if (this.history_on)
this.history = {{sender, text, time()}, @this.history};
if (length(this.history) > this.history_max)
this.history = this.history[1..this.history_max];
endif
endif
if (is_player(this.location) && (!(this.location in connected_players())))
if (is_a(sender, $player))
sender:tell("Your wristpad buzzes: Target is asleep.  Please try another time.");
endif
elseif ((!is_a(sender, $immortal)) && is_a(this.location, $immortal))
sender:tell("Your wristpad buzzes: Target is asleep.  Please try another time.");
endif
endif

match_wristpad

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

name = args[1];
if (name == "help")
return $rpg.help_wristpad;
endif
if (name == "fcpd")
return $rpg.fcpd_wristpad;
endif
if (valid(who = $su:match_player(name)))
return who;
elseif (valid(who = $rpg:match_wristpad(name, player)))
return who;
else
return #-1;
endif

throw toss

Spec this any anyFlags rxdOwner #361Definer #130

Referenced by

none

Source

player:tell("You can't throw your wristpad.  Sorry.");

stash

Spec this none noneFlags rxdOwner #361Definer #130

Referenced by

none

Source

player:tell("You can't stash your wristpad.  Sorry.");

switch

Spec this at/to anyFlags rxdOwner #361Definer #130

Referenced by

none

Source

"Switch between 'normal' and 'filter'";
modenumber = iobjstr in {"normal", "filter"};
if (!modenumber)
player:tell("Valid options are 'normal' and 'filter");
return;
endif
"I am dumb and made the modes zero-indexed.";
modenumber = modenumber - 1;
this.mode = modenumber;
player:aat($su:ps(this.toggle_msg));

ignore unignore

Spec any on top of/on/onto/upon thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

"Add or remove a specific player from your wristpad's ignore list.";
who = $su:match_player(dobjstr);
if (!valid(who))
player:tell(verb, " who?");
return;
endif
if (who.programmer)
player:tell("You cannot ignore ", who.name, ".");
return;
endif
if (verb == "ignore")
if (who in this.ignore)
player:tell("You are already ignoring pages from ", who.name, ".");
return;
else
this.ignore = setadd(this.ignore, who);
player:tell(who:dnamec(), " added to ignore list.");
endif
else
if (!(who in this.ignore))
player:tell("You are not ignoring pages from ", who.name, ".");
return;
else
this.ignore = setremove(this.ignore, who);
player:tell(who:dnamec(), " removed from ignore list.");
endif
endif

ignored

Spec none on top of/on/onto/upon thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

"List currently ignored players.";
if (length(this.ignore) > 0)
player:tell("Your wristpad lists the following ignored people:");
for p in (this.ignore)
player:tell(p.name);
endfor
else
player:tell("You are not ignoring anyone.");
endif

moveto

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

where = args[1];
if (is_a(this.registered_user, $player) && (where != this.registered_user))
return 0;
endif
return pass(@args);

look_self

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

pass(@args);
player:tell("A small glyph on the LCD shows the time: ", $ansi.bold_on, $time:ctime(), $ansi.bold_off, ".  It is ", $time.day_segments[$time:day_segment()], ".");
player:tell("In a corner of the clock readout, a tiny meter shows ", $ansi.bold_on, "lag: ", $ansi.reset, $flywheel:lagstr(), ".");
if (this.alarm_time)
player:tell("The alarm is set for ", $ansi.bold_on, $ansi.red, this.alarm_time, $ansi.reset, ".");
endif
if (this.radio_on)
player:tell("The radio is on, tuned to code channel #", this.frequency, ".");
else
player:tell("The radio is off.");
endif
if (this.history_on)
player:tell("The page history is on.");
else
player:tell("The page history is off.");
endif
if (valid(hol = $time:holiday_today()))
player:tell("Oh hey -- it's ", hol.name, ".  ", hol.description);
endif
player:tell("The credit chip's tiny display reads: ", $ansi.green, "$", $su:group_number(this.registered_user.credit), $ansi.reset, ".");

alarm

Spec this is anyFlags rxdOwner #361Definer #130

Referenced by

none

Source

"Set an alarm in hh:mm 24-hour format.";
ctim = iobjstr;
if (((i = index(ctim, ":")) && (i > 1)) && (length(ctim) > i))
hh = toint(ctim[1..i - 1]);
mm = toint(ctim[i + 1..$]);
ctim = (hh > 9) ? "" | "0";
ctim = (ctim + tostr(hh)) + ":";
ctim = ctim + ((mm > 9) ? "" | "0");
ctim = ctim + tostr(mm);
this.alarm_time = ctim;
player:tell("You set your wristpad's alarm for ", $ansi.bold_on, $ansi.red, ctim, $ansi.reset, ".");
player:aat(player:dnamec(), " taps a button on ", player.pp, " wristpad.");
return;
endif
player:tell("Huh?  Try giving a time in hh:mm 24-hour format (like 16:00 for 4pm).");

alarm_check

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

hhmm = $time:ctime()[12..15];
if (hhmm == this.alarm_time[1..$ - 1])
if (valid(this.location))
this.registered_user:tell("");
this.registered_user:tell($ansi.bold_on, "Your wristpad vibrates and beeps loudly.  It's ", $ansi.red, this.alarm_time, $ansi.white, ".", $ansi.reset);
endif
who = this.registered_user;
if (is_a(who.body, $body))
who = who.body;
endif
valid(who.location) && who.location:announce_all_but({who}, ((who:dnamec() + "'s ") + this.name) + " beeps loudly.");
this.alarm_time = "";
endif

radio

Spec any any anyFlags rxdOwner #361Definer #130

Referenced by

none

Source

"Configure the radio, eg. 'radio on', 'radio off', 'radio <frequency>', or 'radio key=mysecretkey'.";
if (prepstr == "on")
if (this.radio_on)
player:tell("It's already on.");
else
this.radio_on = 1;
player:tell("You turn on the radio on your wristpad.");
endif
elseif (prepstr == "off")
if (!this.radio_on)
player:tell("It's already off.");
else
this.radio_on = 0;
player:tell("You turn off your wristpad radio.");
endif
elseif ((channel = toint(dobjstr)) > 0)
if (!this.radio_on)
player:tell("Your wristpad radio isn't turned on.");
return;
endif
player:tell("You tune your wristpad radio to channel #", channel, ".");
$radio:tune_out(this, this.frequency);
this.frequency = channel;
$radio:tune_in(this, channel);
elseif ((length(argstr) >= 4) && (argstr[1..4] == "key="))
key = argstr[5..$];
if (!key)
player:tell($su:ps("You remove the decryption key configuration from your %t."));
else
player:tell($su:ps("You set the decryption key on your %t to '"), key, "'.");
endif
this.key = key;
elseif (!dobjstr)
if (!this.radio_on)
player:tell("Your wristpad radio is off.  Use 'radio on' to turn it on.");
else
player:tell("Your wristpad radio is tuned to frequency ", this.frequency, ".");
if (this.key)
player:tell("The decryption key is set to '", this.key, "'.");
else
player:tell("No decryption key is set.");
endif
endif
else
player:tell("Usage:  radio <on|off>   Turn the radio on or off.");
player:tell("        radio <freq>     Tune the radio to a specific frequency.");
player:tell("        radio key=<key>  Tune the radio to a specific encryption key.");
endif

radio_receive

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

{freq, msg} = args;
if (this.radio_on && valid(this.location))
if (freq == this.frequency)
this.registered_user:tell("On your ", this:name(), " radio: ", $ansi.cyan, $su:decrypt(msg, this.key), $ansi.reset);
endif
endif

give

Spec this at/to anyFlags rxdOwner #361Definer #130

Referenced by

none

Source

return player:tell("You can't give your ", this:name(), " away.");

add_transaction

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

{amount, target} = args;
if (!gamevalid(target))
target_name = "unknown";
"return;";
else
target_name = strsub(target:iname(), "generic ", "");
endif
this.transactions = {@this.transactions, {amount, target_name, time()}};
n = this.max_transactions;
if (length(this.transactions) > n)
this.transactions = this.transactions[$ - (n - 1)..$];
endif

check*book

Spec this none noneFlags rxdOwner #361Definer #130

Referenced by

none

Source

"List your 10 most recent credit transactions. Use 'check wrist for <number>' for more than 10.";
this:_do_check(10);

history

Spec any any anyFlags rxdOwner #361Definer #130

Referenced by

none

Source

"Toggle or view the page history, eg. 'history on', 'history off', 'history clear', or 'history'.";
if (prepstr == "on")
if (this.history_on)
player:tell("Page history is already on.");
else
this.history_on = 1;
player:tell("You turn on the page history on your wristpad.");
endif
elseif (prepstr == "off")
if (!this.history_on)
player:tell("Page history is already off.");
else
this.history_on = 0;
player:tell("You turn off the page history on your wristpad.");
endif
elseif (dobjstr == "clear")
if (!this.history)
player:tell("Your wristpad page history is already empty.");
return;
endif
this.history = {};
player:tell("You clear the page history on your wristpad.");
elseif (!dobjstr)
if (!this.history_on)
player:tell("Your wristpad page history is off.  Use 'history on' to turn it on.");
endif
if (!this.history)
player:tell("Your wristpad page history is empty.");
else
player:tell("You check the page history on your wristpad.");
for h in (this.history)
if (length(h) > 2)
ts = tostr($time_utils:longdate(h[3]), " ", $time_utils:ampm(h[3]));
ts = tostr($ansi.cyan, ts, $ansi.reset);
else
ts = " unknown                         ";
endif
player:tell("[", ts, "] ", h[1].name, ": ", $ansi.bold_on, h[2], $ansi.reset);
endfor
endif
else
player:tell("Usage:  history <on|off>   Turn the page history on or off.");
player:tell("        history clear      Erase all saved pages.");
player:tell("        history            View your page history.");
endif

can_send_long_message

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

• #130:_page line 18: this:can_send_long_message

Source

{from, to} = args;
if ((!is_player(from)) || (!is_player(to)))
return 1;
elseif (from.programmer || to.programmer)
return 1;
elseif (from in to.friends)
return 1;
elseif ((is_a(from.party, $party) && is_a(to.party, $party)) && (from.party == to.party))
return 1;
elseif ((is_a(from.employer, $biz) && is_a(to.employer, $biz)) && (from.employer == to.employer))
return 1;
endif
return 0;

_init

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

{who} = args;
this.registered_user = who;
who.wristpad = this;

_do_check

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

• #130:check*book line 2: this:_do_check
• #130:check*book line 7: this:_do_check

Source

{n} = args;
player:tell($ansi.bold_on, "Most recent ", n, " credit transactions:", $ansi.reset);
player:tell($ansi.bg_blue, $ansi.white, $ansi.bold_on, $ansi.underline_on, "Amount     To                            When          ", $ansi.reset);
txns = this.transactions[max(1, $ - (n - 1))..$];
for x in (txns)
{amt, who, t} = x;
if (amt < 0)
amt = ((($ansi.red + $ansi.bold_on) + "$") + $su:left(tostr(amt), -10)) + $ansi.reset;
else
amt = ((($ansi.green + $ansi.bold_on) + "$") + $su:left(tostr(amt), -10)) + $ansi.reset;
endif
who = (typeof(who) == OBJ) ? who:iname() | who;
who = ($ansi.bold_on + $su:left(who, -30)) + $ansi.reset;
t = $time:duration((time() - t) * 8) + " ago";
player:tell(amt, who, t);
endfor

check*book

Spec this for/about anyFlags rxdOwner #361Definer #130

Referenced by

none

Source

"List a specific number of transactions.";
n = toint(iobjstr);
if ((n < 1) || (n > this.max_transactions))
player:tell("Usage: check [<n>]  -- n, if present, must be a number between 1 and ", this.max_transactions, ".");
return;
endif
this:_do_check(n);

on_spawn

Spec this none thisFlags rxdOwner #361Definer #130

Referenced by

none

Source

"lol";